Question

Desarrollar un algoritmo en pseudocódigo que permita registrar el número de N vehículos que han entrado en una playa de estacionamiento y computar cada boleta de pago donde se especifica el tipo de vehículo y la cantidad de horas. Calcular el monto total recaudado en un día en el cual han entrado Autos, Camiones y Omnibuses, sabiendo que cada auto paga 4 soles por hora, cada Camión paga 10 soles la hora y cada Ómnibus paga 20 soles la hora.

Considerar:

Documentación del algoritmo (2 puntos)
Definición de variables (1 punto)
Uso correcto de estructuras condicionales (1 puntos)
Calcular el monto total recaudado (1 puntos)
Mostrar los datos de salida (2 puntos)

Answer 1

Pseudocódigo Pseint de facturación en estacionamiento, y contabilidad de vehículos por tipo.  Se adjunta imagen de salida del algoritmo.

Algoritmo boletaEstacionamientoPlaya

• // Definir variables

Definir contadorA,contadorC,contadorO Como Entero

Definir precioA,precioC,precioO,_autos,_camion,_omnibus Como Real

contadorA <- 0

contadorC <- 0

contadorO <- 0

_autos <- 0

_camion <- 0

_omnibus <- 0

precioA <- 4

precioC <- 10

precioO <- 20

• // Ingrese datos

Repetir

 Escribir '1.- Auto (4 s./h) '

 Escribir '2.- Camión (10 s./h) '

 Escribir '3.- Ómnibus (20 s./h) '

 Escribir '0.- Salir '

 Repetir

  Leer res

  Si  NO (res=1 O res=2 O res=3 O res=0) Entonces

   Escribir 'Entrada inválida'

  FinSi

 Hasta Que res=1 O res=2 O res=3 O res=0

•  // Procesar datos

 Segun res  Hacer

  1:

   Escribir 'Cantidad de horas: ' Sin Saltar

   Repetir

    Leer cant

    Si cant<=0 Entonces

     Escribir 'Entrada inválida'

    FinSi

   Mientras Que cant<=0

   contadorA <- contadorA+1

   _autos <- _autos+(precioA*cant)

   Escribir 'Total a pagar (S/.) ' ,precioA*cant

  2:

   Escribir 'Cantidad de horas: ' Sin Saltar

   Repetir

    Leer cant

    Si cant<=0 Entonces

     Escribir 'Entrada inválida'

    FinSi

   Mientras Que cant<=0

   contadorC <- contadorC+1

   _camion <- _camion+(precioC*cant)

   Escribir 'Total a pagar (S/.) ' ,precioC*cant

  3:

   Escribir 'Cantidad de horas: ' Sin Saltar

   Repetir

    Leer cant

    Si cant<=0 Entonces

     Escribir 'Entrada inválida'

    FinSi

   Mientras Que cant<=0

   contadorO <- contadorO+1

   _omnibus <- _omnibus+(precioO*cant)

   Escribir 'Total a pagar (S/.) ' ,precioO*cant

 FinSegun

Hasta Que res==0

• // Imprimir resultados

Escribir ' '

Escribir '   El total pagado (S/.)'

Escribir ' '

Escribir 'Auto: ',_autos

Escribir 'Camión: ',_camion

Escribir 'Ómnibus: ',_omnibus

Escribir ' '

Escribir '  Cantidad de vehículos'

Escribir ' '

Escribir 'Auto: ',contadorA

Escribir 'Camión: ',contadorC

Escribir 'Ómnibus: ',contadorO

FinAlgoritmo

Para saber más acerca de programas con condicionales múltiples consulte: https://brainly.lat/tarea/18042190

#SPJ1