Question

Se debe crear dos matrices de 4x6 enteras y determinar lo siguiente:


Cuántos elementos tienen en común las dos matrices.

Si el mayor número primo de una matriz está repetido en la otra matriz.

Si el promedio de las “esquinas” de una matriz es igual al promedio de las “esquinas” de la otra matriz.

Si la cantidad de números pares almacenados en una matriz es igual a la cantidad de números pares almacenados en la otra matriz.


En base al planteamiento de la problemática, el estudiante debe realizar las siguientes tareas:


Análisis del problema, encontrar las: entradas, procesos y salidas


Listado de variables que se usarán en el algoritmo. En este punto se debe realizar la siguiente tabla con las variables definidas:


Miniespecificación

Diagrama de flujo

Prueba de escritorio

En Pseudocódigo Pseint
Por favor ayuda!!

Answer 1

A continuación algoritmo en pseint, diagrama de flujo, tabla de variables, y salida por pantalla de programa de comparación de dos matrices.  

Pseudocódigo en pseint que opera dos matrices, compara sus elementos, determina números pares, primos, entre otros.

Algoritmo matriz4x6

• // primer paso: definir matrices y variables

Definir indice,repetido,contadorP,contadorC,paresM1,paresM2,primoMayor,contador,matriz1,matriz2,primos Como Entero

Definir promedioM1,promedioM2 Como Real

Dimension matriz1[6,4]

Dimension matriz2[6,4]

Dimension primos[24]

• // Entrada de datos matriz1 y matriz2

Escribir 'Ingrese contenido de la matriz 1:  '

j <- 0

Repetir

 j <- j+1

 i <- 0

 Repetir

  repetido <- 0

  i <- i+1

  Escribir 'elemento (',i,',',j,'): ' Sin Saltar

  Repetir

   Leer matriz1[i,j]

   repetido <- 0

   Para x<-j Hasta 1 Con Paso -1 Hacer

    Para p<-i Hasta 1 Con Paso -1 Hacer

     Si matriz1[i,j]=matriz1[p,x] Entonces

      repetido <- repetido+1

     FinSi

    FinPara

   FinPara

  Mientras Que repetido<>1

 Hasta Que i=6

Hasta Que j=4

Escribir '  '

Escribir 'Ingrese contenido de la matriz 2:  '

j <- 0

Repetir

 j <- j+1

 i <- 0

 Repetir

  repetido <- 0

  i <- i+1

  Escribir 'elemento (',i,',',j,'): ' Sin Saltar

  Repetir

   Leer matriz2[i,j]

   repetido <- 0

   Para x<-j Hasta 1 Con Paso -1 Hacer

    Para p<-i Hasta 1 Con Paso -1 Hacer

     Si matriz2[i,j]=matriz2[p,x] Entonces

      repetido <- repetido+1

     FinSi

    FinPara

   FinPara

  Mientras Que repetido<>1

 Hasta Que i=6

Hasta Que j=4

• // Proceso de datos 1: Cuántos elementos tienen en común las dos matrices

contadorC <- 0

Para j<-1 Hasta 4 Hacer

 Para i<-1 Hasta 6 Hacer

  Para p<-1 Hasta 4 Hacer

   Para s<-1 Hasta 6 Hacer

    Si matriz1[i,j]=matriz2[s,p] Entonces

     contadorC <- contadorC+1

    FinSi

   FinPara

  FinPara

 FinPara

FinPara

• // Proceso de datos 2: Determinar si el mayor número primo de una matriz está repetido en la otra matriz

indice <- 0

Para j<-1 Hasta 4 Hacer

 Para i<-1 Hasta 6 Hacer

  contador <- 0

  Para x<-matriz1[i,j] Hasta 1 Con Paso -1 Hacer

   resto <- matriz1[i,j] MOD x

   Si resto=0 Entonces

    contador <- contador+1

   FinSi

  FinPara

  Si contador=2 Entonces

   indice <- indice+1

   primos[indice] <- matriz1[i,j]

  FinSi

 FinPara

FinPara

primoMayor <- 0

Para p<-1 Hasta indice Hacer

 Si primos[p]>primoMayor Entonces

  primoMayor <- primos[p]

 FinSi

FinPara

contadorP <- 0

Para p<-1 Hasta 4 Hacer

 Para s<-1 Hasta 6 Hacer

  Si primoMayor=matriz2[s,p] Entonces

   contadorP <- contadorP+1

  FinSi

 FinPara

FinPara

• // Proceso de datos 3: determinar si el promedio de las "esquinas" de una matriz es igual al promedio de las "esquinas" de la otra matriz 2

promedioM1 <- (matriz1[1,1]+matriz1[1,4]+matriz1[6,1]+matriz1[6,4])/4

promedioM2 <- (matriz2[1,1]+matriz2[1,4]+matriz2[6,1]+matriz2[6,4])/4

• // Proceso de datos 4: Determinar si la cantidad de números pares en la matriz 1 es igual a la cantidad de números pares de la otra matriz 2

paresM1 <- 0

Para j<-1 Hasta 4 Hacer

 Para i<-1 Hasta 6 Hacer

  residuo <- matriz1[i,j] MOD 2

  Si (residuo==0) Entonces

   paresM1 <- paresM1+1

  FinSi

 FinPara

FinPara

paresM2 <- 0

Para j<-1 Hasta 4 Hacer

 Para i<-1 Hasta 6 Hacer

  resto <- matriz2[i,j] MOD 2

  Si resto=0 Entonces

   paresM2 <- paresM2+1

  FinSi

 FinPara

FinPara

• // Salida de la información: Mostrar datos en pantalla

Escribir ' '

Escribir '**************RESULTAOS******************'

Escribir 'Cantidad de elementos comunes: ',contadorC

Si contadorP<>0 Entonces

 Escribir 'El mayor número primo de la matriz 1 es: ',primoMayor,' y está repetido en la matriz 2'

FinSi

Si promedioM1=promedioM2 Entonces

 Escribir 'Promedio de las esquinas matriz 1 es igual a: ',promedioM1,' y es igual al promedio de la matriz 2'

SiNo

 Escribir 'Promedio de las esquinas matriz 1 es igual a ',promedioM1,' y es diferente al promedio de la matriz 2 que es: ',promedioM2

FinSi

Si paresM1=paresM2 Entonces

 Escribir 'La cantidad de números pares en la matriz 1 es igual a: ',paresM1,' y es igual al de la matriz 2'

SiNo

 Escribir 'La cantidad de números pares en la matriz 1 es igual a: ',paresM1,' y es diferente al de la matriz 2 que es: ',paresM2

FinSi

FinAlgoritmo

Para saber más acerca de algoritmo en pseint de comparación de matrices consulte: https://brainly.lat/tarea/9253072

#SPJ1