Realiza un programa que calcule porcentaje de aprobados, porcentaje de reprobados y moda de la materia Programación Orientada a
Objetos I, con un listado mínimo de 10 estudiantes y al finalizar debe imprimir el listado de los estudiantes indicando el nivel de desempeño
de cada uno y las estadísticas generales de la materia.
2. Para ello deberás solicitar se ingrese la calificación de cada alumno y deberás hacer uso de las estructuras de control
Respuestas a la pregunta
El programa en PSeint para encontrar el porcentaje de aprobados y reprobados al igual que la moda en la materia de programación orientada a objetos es:
Algoritmo porcentajesEstudiantes
Dimension paraModa[20]
Dimension calificaciones[10]
Dimension listado[10,2]
aprobados<-0
reprobados<-0
//inicializamos ventos que almacenara conteo para la moda
Para i<-1 Hasta 20 Con Paso 1 Hacer
paraModa[i]<-0
Fin Para
Para i<-1 Hasta 10 Con Paso 1 Hacer
Escribir "Ingrese Nombre"
Leer listado[i,1]
cal<-1
Escribir "Ingrese calificacion"
Leer cal
//contamos aprobados y desaprobados
calificaciones[i]<-cal
paraModa[cal]<-paraModa[cal]+1
Si cal>10 Entonces
aprobados<-aprobados+1
listado[i,2]<-"Aprobado"
SiNo
reprobados<-reprobados+1
listado[i,2]<-"Reprobado"
Fin Si
Fin Para
//ahora buscamos la ubicacion con mayor conteo para
//hallar la moda
mayorConteo<- -100
Para i<-1 Hasta 20 Con Paso 1 Hacer
Si paraModa[i]>mayorConteo Entonces
mayorConteo<-paraModa[i]
moda<-i
Fin Si
Fin Para
Escribir "Porcentaje de Aprobados: ", aprobados*100/10
Escribir "Porcentaje de Reprobados: ", reprobados*100/10
Escribir "Moda: ", moda
Para i<-1 Hasta 10 Con Paso 1 Hacer
Escribir "Alumno: ", listado[i,1]," Nivel: ",listado[i,2]
Fin Para
FinAlgoritmo
Dado que no indica el lenguaje de programación utilizamos PSeint para crear el algoritmo que luego puede ser exportado hacia cualquier otro lenguaje.
Asumimos el rango de notas entre 1 y 20, y de 10 hacia abajo, reprobados y de 11 hacia arriba aprobados.
El cálculo de la moda presenta un artificio, las calificaciones están representadas por los índices del arreglo llamado paraModa y el valor de cada espacio acumulará la frecuencia con la que aparece dicha calificación o índice:
paraModa[cal]<-paraModa[cal]+1
cal es calificación y es el índice del vector
Finalmente, utilizamos ejemplo de prueba:
NOMBRE NOTA
A 14
B 15
C 14
D 14
E 13
F 18
G 13
H 8
I 9
J 12