Question

Realiza los siguientes ejercicios.

1 Realice y represente mediante un diagrama de flujo el algoritmo para obtener la matriz transpuesta de cualquier matriz de orden M x N.

2 Realice y represente mediante un diagrama de flujo el algoritmo para obtener el producto de dos matrices de orden M x N y P x Q. 3 Realice y represente mediante diagrama de flujo y pseudocódigo un algoritmo que lea un arreglo de M filas y N columnas y que calcule la suma de los elementos de la diagonal principal.​

Answer 1

Respuesta:

listo bro

Explicación paso a paso:

espero te ayude

Answer 2

A continuación tres pseudocódigos Pseint con arreglos bidimensionales, calcular la transpuesta de una matriz, producto de dos matrices, y suma de los elementos de la diagonal principal.

Algoritmo matrizTranspuesta

• // Definir e inicializar variables

Definir fil,col Como Entero

Definir a,b Como Caracter

• // Ingresar tamaño de las matrices

Escribir 'Ingrese valor de M (columna de la matriz): ' Sin Saltar

Repetir

 Leer m

Hasta Que m>0

Escribir 'Ingrese valor de N (fila de la matriz): ' Sin Saltar

Repetir

 Leer n

Hasta Que n>0

Dimension a[n,m]

Dimension b[m,n]

• // generar datos de la matriz

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  a[fil,col]<-ConvertirATexto(fil)+ConvertirATexto(col)

 FinPara

FinPara

• // Mostrar matriz normal

Escribir ''

Escribir 'Matriz normal'

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  Escribir a[fil,col],' ' Sin Saltar

 FinPara

 Escribir ''

FinPara

• // generar datos de la matriz transpuesta

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  b[col,fil]<-a[fil,col]

 FinPara

FinPara

• // Mostrar matriz transpuesta

Escribir ''

Escribir 'Matriz transpuesta'

Para col<-1 Hasta m Hacer

 Para fil<-1 Hasta n Hacer

  Escribir b[col,fil],' ' Sin Saltar

 FinPara

 Escribir ''

FinPara

FinAlgoritmo

Algoritmo MultMatrices

• // Definir e inicializar variables

Definir a, b, fil,col Como Entero

• // Ingresar tamaño de las matrices

Escribir 'Ingrese valor de M (columna de la matriz 1): ' Sin Saltar

Repetir

 Leer m

Hasta Que m>0

Escribir 'Ingrese valor de N (fila de la matriz 1): ' Sin Saltar

Repetir

 Leer n

Hasta Que n>0

Escribir 'Ingrese valor de P (columna de la matriz 2): ' Sin Saltar

Repetir

 Leer p

Hasta Que p>0

Escribir 'Ingrese valor de Q (fila de la matriz 2): ' Sin Saltar

Repetir

 Leer q

 si no (q>0 y q = m) Entonces

  si no (q=m) Entonces

   Escribir "q debe ser igual a m"

  SiNo

   Escribir "Entrada inválida"

  FinSi

 FinSi

Hasta Que q>0 y q = m

Dimension a[n,m]

Dimension b[q,p]

Dimension c[n,p]

• // generar datos de la matriz 1

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  a[fil,col]<-azar(9)+1

 FinPara

FinPara

• // Mostrar matriz 1

Escribir ''

Escribir 'Matriz 1'

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  Escribir a[fil,col],' ' Sin Saltar

 FinPara

 Escribir ''

FinPara

• // generar datos de la matriz 2

Para fil<-1 Hasta q Hacer

 Para col<-1 Hasta p Hacer

  b[fil,col]<-azar(9)+1

 FinPara

FinPara

• // Mostrar matriz 2

Escribir ''

Escribir 'Matriz 2'

Para fil<-1 Hasta q Hacer

 Para col<-1 Hasta p Hacer

  Escribir b[fil,col],' ' Sin Saltar

 FinPara

 Escribir ''

FinPara

• // generar producto de las dos matrices

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta p Hacer

  c[fil, col]<-0;

  Para k<-1 Hasta q Hacer

   c[fil, col]<-c[fil, col] + a[fil, k] * b[k, col];

  FinPara

 FinPara

FinPara

• // Mostrar el producto de las dos matrices

Escribir ''

Escribir 'Matriz 1 x Matriz 2'

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta p Hacer

  Escribir c[fil,col],' ' Sin Saltar

 FinPara

 Escribir ''

FinPara

FinAlgoritmo

Algoritmo sumaDiagonalPrincipal

• // Definir e inicializar variables

Definir a,fil,col,suma Como Entero

suma <- 0

• // Ingresar tamaño de la matriz

Escribir 'Ingrese valor de M (columna de la matriz): ' Sin Saltar

Repetir

 Leer m

Hasta Que m>0

Escribir 'Ingrese valor de N (fila de la matriz): ' Sin Saltar

Repetir

 Leer n

 Si  NO (n>0 Y n=m) Entonces

  Si  NO (n=m) Entonces

   Escribir 'n debe ser igual a m'

  SiNo

   Escribir 'Entrada inválida'

  FinSi

 FinSi

Hasta Que n>0 Y n=m

Dimension a[n,m]

• // generar datos de la matriz

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  a[fil,col]<-azar(9)+1

 FinPara

FinPara

Escribir ''

• // Mostrar matriz

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  Escribir a[fil,col],' ' Sin Saltar

 FinPara

 Escribir ''

FinPara

• // Mostrar y sumar los elementos de la diagonal principal

Escribir 'Elementos de la diagonal principal'

Para fil<-1 Hasta n Hacer

 Para col<-1 Hasta m Hacer

  Si fil=col Entonces

   Escribir a[fil,col],' ' Sin Saltar

   suma <- suma+a[fil,col]

  FinSi

 FinPara

FinPara

Escribir ''

• // Mostrar resultado de la suma de los elementos de la diagonal principal

Escribir 'La suma de los elementos de la diagonal principal es: ',suma

FinAlgoritmo

Para saber más acerca de algoritmo pseint con matrices consulte:

https://brainly.lat/tarea/10903025  

https://brainly.lat/tarea/20215168  

https://brainly.lat/tarea/21414594

#SPJ2